10 REM * SPRITE BEISPIEL 3 *
20 REM DAS HEISSLUFTMONSTER
30 VIC=13*4096:REM HIER BEGINNEN DIE VIC-REGISTER
35 POKE VIC+21,1:REM EINSCHALTEN SPRITE 0
36 POKE VIC+33,14:REM HINTERGRUNDFARBE HELLBLAU
37 POKE VIC+23,1:REM SPRITE 0 IN Y VERDOPPELN
38 POKE VIC+29,1:REM UND IN X
40 POKE 2040,192:REM SPRITEZEIGER 0 AUF BLOCK 192
50 POKE VIC+28,1:REM MEHRFARBENMODUS SPRITE 0
60 POKE VIC+37,7:REM FARBREGISTER 0 SETZEN
70 POKE VIC+38,4:REM FARBREGISTER 1 SETZEN
180 POKE VIC,100:REM X-POSITION SPRITE 0
190 POKE VIC+1,100:REM UND Y-POSITION
220 POKE VIC+39,2:REM FARBE SPRITE 0
250 FOR Y=0 TO 63
300 READ A:REM SPRITEDATEN LESEN
310 POKE 192*64+Y,A:REM UND EINTRAGEN
320 NEXT Y
330 DX=1:DY=1
340 X=PEEK(VIC):REM X-POSITION PRUEFEN
350 Y=PEEK(VIC+1):REM Y-POSITION TESTEN
360 IF Y=50 OR Y=208 THEN DY=-DY:REM BEI RANDPOSITION DY UMKEHREN
380 IF X=24 AND (PEEK(VIC+16)AND 1)=0 THEN DX=-DX:REM WENN SPRITE
390 REM AM LINKEN RAND (X<24 UND MSB=0) DANN DX UMKEHREN
400 IF X=40 AND (PEEK(VIC+16)AND 1)=1 THEN DX=-DX:REM WENN SPRITE
410 REM AM RECHTEN RAND (X=40 UND MSB=1) DANN DX UMDREHEN
420 IF X=255 AND DX=1 THEN X=-1:SIDE=1
430 REM UMSCHALTEN AUF ANDERE BILDSCHIRMSEITE
440 IF X=0 AND DX=-1 THEN X=256:SIDE=0
450 REM UMSCHALTEN AUF ANDERE BILDSCHIRMSEITE
460 X=X+DX:REM ADDIEREN VON DX ZU X
470 X=X AND 255:REM SICHERSTELLEN DASS X IM ERLAUBTEN BEREICH
480 Y=Y+DY
485 POKE VIC+16,SIDE
490 POKE VIC,X:REM NEUE X-POSITION SPRITE 0
510 POKE VIC+1,Y:REM NEUER Y-WERT
520 GETA$:REM ERWARTET TASTENDRUCK
521 IF A$="M" THEN POKE VIC+28,1:REM UMSCHALTEN AUF MULTICOLORSPRITE
522 IF A$="H" THEN POKE VIC+28,0:REM UMSCHALTEN AUF HIRES-SPRITE
530 GOTO 340
600 REM ***** SPRITE DATEN *****
610 DATA 64,0,1,16,170,4,6,170,144,10,170,160,42,170,168,41,105,104,169,235,106
620 DATA 169,235,106,169,235,106,170,170,170,170,170,170,170,170,170,170,170,170
630 DATA 166,170,154,169,85,106,170,85,170,42,170,168,10,170,160,1,0,64,1,0,64
640 DATA 5,0,80,0